component ExploreAnime(animes []*arn.Anime, year string, status string, typ string, user *arn.User)
	#filter-root(data-url="/explore/anime")
	ExploreFilters(year, status, typ, false)

	.corner-buttons-hide-on-mobile
		if user != nil
			button.action(data-trigger="click", data-action="hideAddedAnime", title="Hide anime in my collection")
				RawIcon("eye-slash")
		
		a.button(href="/halloffame", title="Hall of Fame")
			RawIcon("trophy")
		
		a.button(href="/genres", title="View genres")
			RawIcon("clone")
		
		if user != nil
			a.button(href="/explore/sequels", title="View sequels of my completed anime")
				RawIcon("forward")
		
		a.button(href="/explore/color/any/anime", title="View colors")
			RawIcon("paint-brush")

	h1.page-title Explore

	.explore-anime
		if len(animes) == 0
			p.no-data.mountable No anime found using the above filters.
		else
			AnimeGrid(animes, user)

component ExploreFilters(year string, status string, typ string, advancedFilters bool)
	.explore-filters
		select#filter-year.action(value=year, data-action="filterAnime", data-trigger="change")
			if advancedFilters
				option(value="")

			for year := time.Now().Year()+1; year >= 1951; year--
				option(value=year)= year

		select#filter-status.action(value=status, data-action="filterAnime", data-trigger="change")
			if advancedFilters
				option(value="")
			
			option(value="current") Current
			option(value="upcoming") Upcoming
			option(value="finished") Finished

			if advancedFilters
				option(value="tba") TBA

		select#filter-type.action(value=typ, data-action="filterAnime", data-trigger="change")
			if advancedFilters
				option(value="")
			
			option(value="tv") TV
			option(value="movie") Movie
			option(value="ova") OVA
			option(value="ona") ONA
			option(value="special") Special

			if advancedFilters
				option(value="music") Music